OOP Part 1 - Introducing CFCs

View The Results...

index.cfm

<cfscript>
forename = "Jane";
surname = "Smith";
dob = CreateDate( 1970, 6, 25 );

Person = CreateObject( "component", "Person" ).init( forename, surname, dob );

WriteOutput( "<p>" );
WriteOutput( "Name: " & Person.getFullName() & "<br />" );
WriteOutput( "Age: " & Person.getAgeInYears() & "<br />" );
WriteOutput( "</p>" );

WriteOutput( "<p><strong>Jane gets married to Mr Jones</strong></p>" );

Person.setLastName( "Jones" );

WriteOutput( "<p>" );
WriteOutput( "Name: " & Person.getFullName() & "<br />" );
WriteOutput( "Age: " & Person.getAgeInYears() & "<br />" );
WriteOutput( "</p>" );
</cfscript>

Person.cfc

<cfscript>
	/*
	Note: all functions are public and we can't specify argument or return types.
	*/

	function init( firstname, lastname, dateOfBirth ) {
		variables.instance = StructNew();
		setFirstname( arguments.firstname );
		setLastname( arguments.lastname );
		setDateOfBirth( arguments.dateOfBirth );
		return this;
	}

	function getFirstname() {
		return variables.instance.firstname;
	}
	
	function setFirstname( firstname ) {
		variables.instance.firstname = arguments.firstname;
	}
	
	function getLastname() {
		return variables.instance.lastname;
	}
	
	function setLastname( lastname ) {
		variables.instance.lastname = arguments.lastname;
	}
	
	function getDateOfBirth() {
		return variables.instance.dateOfBirth;
	}
	
	function setDateOfBirth ( dateOfBirth ) {
		variables.instance.dateOfBirth = arguments.dateOfBirth;
	}
	function getAgeInYears() {
		return DateDiff( "yyyy", variables.instance.dateOfBirth, Now() );
	}
	
	function getFullname() {
		return getFirstname() & " " & getLastname();
	}
</cfscript>

View The Code...

Name: Jane Smith
Age: 38

Jane gets married to Mr Jones

Name: Jane Jones
Age: 38